10 replies to this topic

[philmo]

i have a CFX-9850 gb plus and i cant figure out how to caltulate the RREF (Row Reduced Echelon Form) with matrices. I need it for my math class. Thanks in advance for your help

[Bob Vila]

RREF?

[philmo]

RREF?

<{POST_SNAPBACK}>

RREF stands for Row Reduced Echelon Form. Does anyone know what to do?

[casiokingdom]

http://charliewatson...fx/appl_cfx.cat
You will find the program Gauselim in it. This is program will do what you want. i've used it before.

[alias4399]

Im sorry, I do not understand what you are asking for. I have not even heard of RREF (Row Reduced Echelon Form?), though I could probably help you with anything else to do with matrices.

[The_AFX_Master]

Is a row reduction of a matrix: if you apply RREF to any square matrix, that determinant is different of zero, you obtain the identity matrix of same dimention.
If you augment an square matrix with the same dimnsion identity, you can do RREF on this matrix, the site ocuped with the ident matrix now is the inverse of the square matrix

You need a Gauss-Jordan program because your calc doesn?t have CAS. Toworrow i will upload the program on the AFX math programs section of the file sharing. The program is step by step,or directly.

You can need RREF for: ??
alternatives:

1.-solve a linear system: You can invert (using ^-1 power elevation) the coefficients matrix, then multiply the answer by the solution vector, do it if the system is greater than 6 eqns

2.- invert a matrix: Use ^-1 power elevation on the RUN mode of your calc.

[caspro]

Charlie Watson's site has row reduction programs in .cat format.

They are listed below in text format which you can type in.
(or use Xchange to transfer them via a cable)

If you have one of the GB plus models then the rowreda program is already built-in.
For more details see:
http://www.angelfire...srefrref1.0.htm

ROWREDA Reduces matrix A to echelon form, storing result in matrix R and indicating type of solution.

ROWREDTT As for ROWREDA but also shows steps in reduction.
(Though rarely shows a neat path to the reduction!)

_ -represents the triangle symbol on the Pgrm menu
=> -implicaton symbol (if,then symbol)
-> -assignment arrow
<> -not equal to
% -represents the fraction symbol on the a b/c button

@@ Program "ROWREDA"

ClrText
"Row reduce matrix A"
Dim Mat A
List Ans1->R
List Ans2->C
Mat A->Mat R
1->I
For 1->J To C
For 1->N To R-I
Mat R[I,J]=0=>Swap R,I,I+N
Next
If Mat R[I,J]<>0
Then *Row 1%Mat R[I,J],R,I
For 1->K To R
K<>I=>*Row+ -Mat R[K,J],R,I,K
Next
Isz I
IfEnd
If I=R+1
Then Mat R[R,J]=1=>Break
Dsz I
IfEnd
Next
2->S
For 2->I To R
If Mat R[I,C-1]=0 And Mat R[I,C]<>0:Then 0->S:IfEnd
Next
If Mat R[R,C-1]<>0:Then 1->S:IfEnd
S=0=>"No solution"_
S=1=>"Unique solution"_
S=2=>"Many solutions"_
Mat R

@@ Program "ROWEDIT"

ClrText
"Row reduce matrix A"
"Tutorial version"_
Dim Mat A
List Ans1->R
List Ans2->C
Mat A->Mat R
1->I
For 1->J To C
For 1->N To R-I
If Mat R[I,J]=0
Then ClrText:Locate 1,3,"Swap rows":Locate 11,3,I:Locate 14,3,"and":Locate 18,3,I+N_
Swap R,I,I+N
Mat R_
IfEnd
Next
If Mat R[I,J]<>0
Then ClrText:Locate 1,3,"x row":Locate 7,3,I:Locate 10,3,"by":Locate 13,3,1%Mat R[I,J]_
*Row 1%Mat R[I,J],R,I
Mat R_
For 1->K To R
If K<>I
Then ClrText:Locate 1,3,"row":Locate 4,3,I:Locate 5,3,"x":Locate 6,3,-Mat R[K,J]:Locate 14,3,"+to row":Locate 21,3,K_
*Row+ -Mat R[K,J],R,I,K
Mat R_
IfEnd
Next
Isz I
IfEnd
If I=R+1
Then Mat R[R,J]=1=>Break
Dsz I
IfEnd
Next
2->S
For 2->I To R
If Mat R[I,C-1]=0 And Mat R[I,C]<>0:Then 0->S:IfEnd
Next
If Mat R[R,C-1]<>0:Then 1->S:IfEnd
S=0=>"No solution"_
S=1=>"Unique solution"_
S=2=>"Many solutions"_
Mat R

[mintsmike]

how do you get "For" and "Next" on the calculator?

For and Next are programming commands that can be accessed from the programming menu. On almost all graphing calculators, this can be attained while editing a program by pressing Shift' /> then OPTN' />

For help on their syntax and usage then go here: http://www.casiocalc...amp;#entry31788

Regards