11 replies to this topic

[Krtyski]

Whack-A-Mole is very traditional action game. fx-5800P is much slower with very limited Casio Basic than fx-9860G II and fx-cf10. So I wanted to know if the action game run on slow fx-5800P by means of CASIO Basic.

The main routine is "WHACK-A-MOLE" and it calls "WAM".


Game title and menu, you can change game settings.
EXE to move to game main.


0 to start the game.


Mole (letter O) appears, and press 1 to 9 key to hit the mole. If you are slow, you will lose LIFE. If you are very slow, you will lose LIFE and PRIZE.


in a mean while (when PRIZE is getting to more than 200 as default), a fake mole (0, zero) appears. If you hit the fake you will lose LIFE.


Sometime fake mole and real mole comes at the same time. Unless you hit only the real mole, you will lose LIFE.


When LIFE is 0 (zero), game is over.

Probably the speed of the mole action is fast enough.

Main Routine "WACK-A-MOLE"

7->M:17->B:25->E
20->F:25->S:200->V

Lbl 0
Cls
" WHACK-A-MOLE"
Locate 5,2,"<0>:SETTINGS"
Locate 6,3,"<EXE>:START"
Locate 8,4,"<AC>:QUIT"

Do
Getkey->K
If K=25:Then
Break:IfEnd
LpWhile K≠47

If K=25:Then Cls
"LIFE"?M
"BURST LIMIT"?B
"TIME-OUT"?E
"FUND"?F
"SHAKE LOSS"?S
"INVOKE FAKE"?V
Goto 0:IfEnd

Prog "WAM"
Goto 0

Game main "WAM"

Lbl 2
M->L:0->P:0->Q
Cls
10->DimZ
35->Z[1]:36->Z[2]
37->Z[3]:21->Z[4]
22->Z[5]:23->Z[6]
31->Z[7]:32->Z[8]
33->Z[9]

For 1->I To 3
Locate 1,I,"[ ][ ][ ]"
Next
Locate 11,2,"PRIZE"
Locate 12,3,P
Locate 1,4,"LIFE:"
Locate 6,4,L
Locate 11,4,"GO:<0>"
While Getkey≠25
WhileEnd
Locate 11,4," "

Lbl 0

RanInt#(1,9)->T
RanInt#(1,3)->X
RanInt#(1,3)->Y
RanInt#(0,3)->Z
RanInt#(1,3)->W
9+X-3Y->N
If P≥V:Then
Z=0=>2->Q
Z=1=>1->Q
Z≥2=>0->Q
Else 0->Q:IfEnd

Lbl 1
Dsz T
Goto 1

0->C
If Q=2:Then
Locate 3X-1,Y,"0"
Else
Q=1=>Locate 3W-1,X,"0"
Locate 3X-1,Y,"O"
IdEnd

Do
Isz C
If C>E:Then
Break:IfEnd
Getkey->K
LpWhile K=0

Q=1=>Locate 3W-1,X," "
Locate 3X-1,Y," "

If Q≤1:Then
If C≤B And K=Z[N]
Then P+F-C->P
Else L-1->L
If C>E:Then
P-S->P:IfEnd
IfEnd
Else
If C≤E:Then
L-1->L:IfEnd
IfEnd

Locate 12,3," "
Locate 12,3,P
Locate 6,4,L

L=>Goto 0

0->DimZ
For 1->I To 3
For 1->J To 3
Locate 3,J-1,I,"0"
Next:Next
Locate 1,2,"GAME OVER"

Locate 10,4,"<EXE> "◣
Cls
Locate 1,2,"GAME OVER"
Locate 2,3,"<0> GO BACK"
Locate 1,4,"<RCL>:TRY AGAIN"
Do
Getkey->K
If K=25 Or K=41
Then Break
IfEnd
LpWhile 1
If K=41:Then
Goto 2:IfEnd
If K=25:Then
Return:IfEnd

Edited by Krtyski, 01 January 2014 - 02:03 PM.

[flyingfisch]

Wow, this really looks nice, keep up the good work

[Krtyski]

Thank you flyingfisch

The game scenario and settings are as follows;


1. Your are a Mole Buster.

2. You get 7 LIFEs when you start the game (this can be changed at settings).

3. You get FUND each time you engage a mole, the default FUND is 20 .

4. You spend cost to kill each mole, the longer you kill the more cost you spend. The cost is increasing after the mole appears until the mole is killed.

5. You gain PRIZE = Fund - Cost

6. You have to kill the mole within LIMIT which is Cost=17 as default. The LIMIT (BURST LIMIT) can be changed. Unless you kill the mole within the LIMIT, you lose one LIFE. The LIMIT can be changed.

7. Mole shakes when you spend Cost=25 (Time-out) as default, then you lose one LIFE and 25 PRIZEs.

8. When your PRIZE gets 200 (default) at first time, fake mode is invoked. The default can be changed.

9. There are 2 fake modes; one fake mole appears and one fake and one real mole appear at the same time.

10. When you kill the fake mole, you lose one LIFE. You have to leave the fake mole goes back.

11. When your LIFE gets 0 (zero), the game is over.


The Cost is running by a loop timer (Do loop) and this timer controls the game, very simple.

Edited by Krtyski, 07 January 2014 - 04:33 AM.

[Tritonio]

This looks so nice... Well done!

[Krtyski]

Thanks, did you enjoy it.

I just wanted to rate performance of fx-5800P, and realized Casio Basic is so nice! 

[Tritonio]

I finally found time to type this in my calc. :-D

 

There is a small typo:

 

Locate 3,J-1,I,"0"

 

Should be

 

Locate 3xJ-1,I,"0"

 

The game is enjoyable though, especially once the fake mole starts coming up, it's not easy!

[Krtyski]

Hi Everyone

 

For easy installation of this program to your fx-5800P, I uploaded zip file that contain the 2 files. These 2 files are ccl file.

Please download the zip file: Whack-a-Mole_5800P.zip

 

Unpack the file to get 2 ccl files and transfer those to your fx-5800P using CcLinker.

You can get CcLinker dongle and application software at CcLinker -  a program copy tool for fx-5800P.

 

 

 

 

Hi Tritonio

 

Thank you for the correction.

 

The original post was long time ago, so I cannot edit the article.

 

I finally found time to type this in my calc. :-D

 

There is a small typo:

 

Locate 3,J-1,I,"0"

 

Should be

 

Locate 3xJ-1,I,"0"

 

The game is enjoyable though, especially once the fake mole starts coming up, it's not easy!

Edited by Krtyski, 13 November 2019 - 02:47 AM.

[CalcLoverHK]

Hi Krtyski

 

Why you can't edit the long-time post? Is there any term that limits such action?

 

Cheers

CalcLoverHK

[Krtyski]

Hi CalcLoverHK

 

It's very simple. I do not see "edit" link on the original article. So I guess it's because of old post, but I'm not sure.

 

 

Hi Krtyski

 

Why you can't edit the long-time post? Is there any term that limits such action?

 

Cheers

CalcLoverHK

[hypdie]

Hey i know i am late and probably no one will rpely to me but my game is not working as it is supposed to be like the moles dont dissapear any help and is IdEnd on purpose or a spelling mistake for IfEnd

[Krtyski]

Hey i know i am late and probably no one will rpely to me but my game is not working as it is supposed to be like the moles dont dissapear any help and is IdEnd on purpose or a spelling mistake for IfEnd

 

The IfEnd is typo, please replace with IfEnd.

 

I'm afraid this is too late reply.

[Krtyski]

Hi everyon

 

If you have CcLinker, a PC link system for fx-5800P, please download from here to easily load this program to your fx-5800P.

 

For CcLinker you can get USB dongle (dedicated hardware) and software at this site. 

- Dongle: buy at this page

- CcLinker:  software download

 

Please enjoy!

Edited by Krtyski, 07 November 2023 - 09:17 AM.